外部程序“ansys speos for parametric"初始化失败

xtxoxk

我安装了speos for parametric，启动后如下图提示，但程序是加载上去了，请高手指点迷津，先谢谢了

xtxoxk

另外，SPEO检索config的目录默认是C:\Users\X\Documents\OPTIS\SPEOS for Creo Parametric 2020 R2\CREO4.0，请问我如何改到其它目录，如D:\Program Files\PTC\config\chs
以下是批处理文件内容
rem @echo off

REM
REM        ANSYS SPEOS for Creo Parametric
REM

REM First argument (Version creo ex:CREO4.0)
SET arg1=%~1
REM ECHO arg1 is %arg1%

REM Second argument (Path to Creo Parametric)
SET arg2=%~2
REM ECHO arg2 is %arg2%

REM Third argument (User path)
SET arg3=%~3
REM Remove ending \
IF NOT "%arg3%" == "" (
        IF %arg3:~-1%==\ (
                SET arg3=%arg3:~0,-1%
        )
)

IF "%arg1%" == "" (
        SET ERROR=First argument is required

        CALL :ShowError
        CALL :ShowHelp
)

set CREO_VERSION=%~1
set "CREO_FOLDER=%CREO_VERSION:CREO=CREO %"

if "%arg2%" == "" (
        SET arg2=C:\Program Files\PTC\%CREO_FOLDER%\Parametric\bin\parametric.exe
)

set SPEOSPTCINSTALLDIR=%~dp0

set SPEOSPTCDLLDIR=%SPEOSPTCINSTALLDIR%\64bits\%CREO_VERSION%

SET PROTKDATSTR=PROTKDAT $SPEOSPTCDLLDIR\protk.dat

IF %SPEOSPTCINSTALLDIR:~-1%==\ SET SPEOSPTCINSTALLDIR=%SPEOSPTCINSTALLDIR:~0,-1%
IF NOT EXIST "%SPEOSPTCINSTALLDIR%" (
        SET ERROR=Path in environment variable SPEOSPTCINSTALLDIR doesn't exist
        CALL :ShowError
        CALL :ShowHelp
)
ECHO  - Add %SPEOSPTCINSTALLDIR% environment variable to the PATH
SET PATH=%PATH%;%SPEOSPTCINSTALLDIR%;%SPEOSPTCDLLDIR%

REM Data directory creation
SET USERPATH=%arg3%
IF "%USERPATH%" == "" (
        SET USERPATH=%USERPROFILE%\Documents
)

IF NOT EXIST "%USERPATH%" (
        SET ERROR=Directory %USERPATH% doesn't exist
        CALL :ShowError
        CALL :ShowHelp
)

IF NOT EXIST "%USERPATH%\OPTIS" (
        MKDIR "%USERPATH%\OPTIS"
)

IF NOT EXIST "%USERPATH%\OPTIS\SPEOS for Creo Parametric 2020 R2" (
        MKDIR "%USERPATH%\OPTIS\SPEOS for Creo Parametric 2020 R2"
)

SET USERSPEOSDIR=%USERPATH%\OPTIS\SPEOS for Creo Parametric 2020 R2

CD /D %USERSPEOSDIR%
IF EXIST "%CREO_VERSION%" (
        ECHO  - Data folder %CREO_VERSION% already exist in %USERSPEOSDIR%
) ELSE (
        ECHO  - Create data folder %USERSPEOSDIR%\%CREO_VERSION%
        MKDIR "%CREO_VERSION%"
)

REM config.pro and config.win creation
CD /D %CREO_VERSION%
IF EXIST "config.pro" (
        ECHO  - Config.pro file already exist
) ELSE (
        ECHO  - Create config.pro file
        ECHO %PROTKDATSTR% > config.pro
)

REM Parametric launch
IF NOT EXIST "%arg2%" (
        SET ERROR=File %arg2% doesn't exist
        CALL :ShowError
        CALL :ShowHelp
)

ECHO  - Launch %arg2%
start "" "%arg2%"

goto :eof

REM Help message
:ShowHelp
@echo off
ECHO Launcher SPEOS for Creo Parametric Application
ECHO Usage:  
ECHO    SPE.bat SPEOSVersion [ParametricExePath] [UserDir]
ECHO.
ECHO With:
ECHO  SPEOSVersion: Describe the version of SPEOS for Creo Parametric application.
ECHO    Could be CREO3.0 for Creo Parametric 3.0 version
ECHO             CREO4.0 for Creo Parametric 4.0 version
ECHO             CREO5.0 for Creo Parametric 5.0 version
ECHO             CREO6.0 for Creo Parametric 6.0 version
ECHO.
ECHO  ParametricExePath: The path to the parametric.exe file.
ECHO    By default C:\Program Files\PTC\Creo 3.0\Parametric\bin\parametric.exe
ECHO                 if SPEOSVersion is CREO3
ECHO               C:\Program Files\PTC\Creo 4.0\Parametric\bin\parametric.exe
ECHO                 if SPEOSVersion is CREO4
ECHO               C:\Program Files\PTC\Creo 5.0\Parametric\bin\parametric.exe
ECHO                 if SPEOSVersion is CREO5
ECHO               C:\Program Files\PTC\Creo 6.0\Parametric\bin\parametric.exe
ECHO                 if SPEOSVersion is CREO6
ECHO.
ECHO  UserDir: Define the path where startup directory will be created
ECHO    By default %USERPROFILE%\Documents
ECHO.
ECHO.
PAUSE
EXIT

REM Popup
:ShowError
@echo off
ECHO %ERROR%
ECHO msgbox "%ERROR%", vbOKOnly+vbCritical, "SPE.bat Error" > %tmp%\tmp.vbs
CSCRIPT /nologo %tmp%\tmp.vbs
DEL %tmp%\tmp.vbs

HerveyHu

看了一下批处理，但是没看懂，Speos的安装包给个链接，谢谢！

外道魔像www

一大串英文我眼睛都花了

xtxoxk

HerveyHu 发表于 2020-10-4 12:40
看了一下批处理，但是没看懂，Speos的安装包给个链接，谢谢！

链接：https://pan.baidu.com/s/1nDQDrO55NzPQurijbafR0g
提取码：4xb7
复制这段内容后打开百度网盘手机App，操作更方便哦

HerveyHu

xtxoxk 发表于 2020-10-6 22:26
链接：https://pan.baidu.com/s/1nDQDrO55NzPQurijbafR0g
提取码：4xb7
复制这段内容后打开百度网盘 ...

谢谢老铁！

xtxoxk

HerveyHu 发表于 2020-10-6 22:29
谢谢老铁！

装好了记得分享经验，我WIN7装好后就卡在初始化这里了